11922911
   
 
|
分享:
▲
▼
看到以上的程式码你可能会想, 那不是每一个插件也要弄一个 json? 
其实不是, 你可以只在一个插件中读取一次json, 再把那个资源物件的id 分享给其他插件使用
以下是使用 XVar 把物件 id 分享给其他插件的方法
需要载入 json 的插件这样写:
复制程式
#include <amxmodx>
#include <oo_assets>
public Assets:AssetsObject;
public plugin_precache()
{
AssetsObject = oo_new("Assets");
AssetsLoadJson(AssetsObject, "assets/test.json");
}
用于简化程序的一个stock function (可写在你的自定义inc中)
复制程式
stock any:GetXVarObject(const name[])
{
new xvar = get_xvar_id(name);
if (xvar == -1)
set_fail_state("XVar does not exist: %s", name);
new any:object = get_xvar_num(xvar);
if (!oo_object_exists(object))
set_fail_state("Object does not exist: %d", object);
return object;
}
这是其他插件A:
复制程式
new Assets:g_oAssets;
public plugin_init()
{
g_oAssets = GetXVarObject("AssetsObject");
register_clcmd("test_mp3", "CmdTestMp3");
}
public CmdTestMp3(id)
{
static music[64];
if (AssetsGetRandomGeneric(g_oAssets, "music", music, charsmax(music)))
client_cmd(id, "mp3 play %s", music);
return PLUGIN_HANDLED;
}
这是其他插件B:
复制程式
new Assets:g_oAssets;
public plugin_init()
{
g_oAssets = GetXVarObject("AssetsObject");
register_clcmd("test_spk", "CmdTestSpk");
}
public CmdTestSpk(id)
{
static spk[64];
if (AssetsGetRandomGeneric(g_oAssets, "spk", spk, charsmax(spk)))
client_cmd(id, "spk %s", spk);
return PLUGIN_HANDLED;
}
JSON档案设定 (这只是个范例)
复制程式
{
"generics" : {
"music" : "sound/test/resident_evil.mp3",
"spk" : "sound/test/door_stuck.wav"
}
}
XVar 的详细使用方法可以看看 a78 大的教学
[ 此文章被11922911在2024-06-19 15:03重新编辑 ]
此文章被评分,最近评分记录| 威望:5 (by amore12) | 理由: 辛苦了!! | |
|
|
|
|
 x2
[1 楼]
From：香港没有资料 | Posted：2024-05-16 05:25 |
|
|
11922911
|
分享:
▲
▼
如果担心效能问题其实可以有一些应对方案
譬如在 plugin_init() 一开始就预先用一个变数来获取某个档案, 以后就用那个变数来设定 (只针对 model 或 sprite)
复制程式
new g_KnifeModel[64];
new g_ShockwaveSpr;
...
public plugin_init()
{
...
AssetsGetModel(g_oAssets, "v_knife", g_KnifeModel, charsmax(g_KnifeModel));
g_ShockwaveSpr = AssetsGetSprite(g_oAssets, "shockwave");
}
public OnKnifeDeploy_Post(ent)
{
...
if (g_KnifeModel[0])
set_pev(player, pev_viewmodel2, g_KnifeModel);
}
public OnWorldSpawnTraceAttack_Post(ent, attacker, Float:damage, Float:direction[3], tr, damagebits)
{
...
if (g_ShockwaveSpr)
{
message_begin_f(MSG_PVS, SVC_TEMPENTITY, origin);
write_byte(TE_BEAMCYLINDER); // TE id
...
write_short(g_ShockwaveSpr);
message_end();
}
}
而 sound 及 generic 则可以预先获取 Array 的 handle
复制程式
new Array:g_aHitWallSound;
new Array:g_aSlashSound;
...
public plugin_init()
{
...
g_aHitWallSound = AssetsGetSound(g_oAssets, "knife_hitwall");
g_aSlashSound = AssetsGetGeneric(g_oAssets, "knife_spk");
}
复制程式
public OnEmitSound(id, channel, const sample[], Float:volume, Float:attn, flags, pitch)
{
...
if (equal(sample[8], "knife_hitwall", 13))
{
if (g_aHitWallSound != Invalid_Array)
{
static sound[64];
ArrayGetRandomString(g_aHitWallSound, sound, charsmax(sound));
emit_sound(id, channel, sound, volume, attn, flags, pitch);
return FMRES_SUPERCEDE;
}
}
if (equal(sample[8], "knife_slash", 11))
{
if (g_aSlashSound != Invalid_Array)
{
static sound[64];
ArrayGetRandomString(g_aSlashSound, sound, charsmax(sound));
client_cmd(0, "spk %s", sound);
return FMRES_SUPERCEDE;
}
}
}
复制程式
stock ArrayGetRandomString(Array:handle, sound[], maxlen)
{
ArrayGetString(handle, random(ArraySize(handle)), sound, maxlen);
}
[ 此文章被11922911在2024-05-16 18:55重新编辑 ]
此文章被评分,最近评分记录| 支持度:100 (by amore12) | 理由: 辛苦了!! | |
|
|
|
|
|
x2
[2 楼]
From：香港没有资料 | Posted：2024-05-16 13:23 |
|
|
|
